SoftPro Developer Forum

I have the following formula that works for HUD and CDF files but cannot figure out how to revise it for CSS orders. Can you please point me in the right direction?

// eRecording Formula - Counts Documents being recorded and charges $4 per document
Value = 0
//HUD Section
If ({{Order.SettlementType}} = "HUD1" and {{Order.HUDOption.Use2009RESPARegulations}} = FALSE) Then
// Looks at the HUD Section 1200 - If the Fee Schedule Type is "Recording" and there is an Amount being charged, charge $4 per Document
Iterate {{Order.HUDs}} From 1 To #{{Order.HUDs}}
Iterate @.Section1200 From 1202 To (1201 + #@.Section1200)
Iterate @.Charges From 1 To #@.Charges
Iterate @.Self{HUD1200SectionCharge}.Fees From 1 To #@.Self{HUD1200SectionCharge}.Fees
//Looks through the 1200 Section for anything with a Fee Schedule Type of "Recording"
If ( @.FeeScheduleType = "Recording" and Not IsEmpty(@.Amount) ) Then
Value = Value + 4
EndIf
Loop
Loop
Loop
Loop

//CDF Section
ElseIf ({{Order.SettlementType}} = "CDF") Then
// Looks at the CDF Section E - If the Fee Schedule Type is "Recording" and there is an Amount being charged, charge $4 per Document
Iterate {{Order.CDFs}} From 1 To #{{Order.CDFs}}
Iterate @.TaxesAndGovernmentFeesSection.Lines From 1 To #@.TaxesAndGovernmentFeesSection.Lines
Iterate @.Charges From 1 To #@.Charges
Iterate @.Self{TaxAndGovernmentDetailCharge}.Fees From 1 To #@.Self{TaxAndGovernmentDetailCharge}.Fees
If ( @.FeeScheduleType = "Recording" and Not IsEmpty(@.Amount) ) Then
Value = Value + 4
EndIf
Loop
Loop
Loop
Loop
EndIf

Hi there,
I've added to the formula the CSS section to count recorded documents.

// eRecording Formula - Counts Documents being recorded and charges $4 per document
Value = 0
//HUD Section
If ({{Order.SettlementType}} = "HUD1" and {{Order.HUDOption.Use2009RESPARegulations}} = FALSE) Then
// Looks at the HUD Section 1200 - If the Fee Schedule Type is "Recording" and there is an Amount being charged, charge $4 per Document
Iterate {{Order.HUDs}} From 1 To #{{Order.HUDs}}
Iterate @.Section1200 From 1202 To (1201 + #@.Section1200)
Iterate @.Charges From 1 To #@.Charges
Iterate @.Self{HUD1200SectionCharge}.Fees From 1 To #@.Self{HUD1200SectionCharge}.Fees
//Looks through the 1200 Section for anything with a Fee Schedule Type of "Recording"
If ( @.FeeScheduleType = "Recording" and Not IsEmpty(@.Amount) ) Then
Value = Value + 4
EndIf
Loop
Loop
Loop
Loop

//CDF Section
ElseIf ({{Order.SettlementType}} = "CDF") Then
// Looks at the CDF Section E - If the Fee Schedule Type is "Recording" and there is an Amount being charged, charge $4 per Document
Iterate {{Order.CDFs}} From 1 To #{{Order.CDFs}}
Iterate @.TaxesAndGovernmentFeesSection.Lines From 1 To #@.TaxesAndGovernmentFeesSection.Lines
Iterate @.Charges From 1 To #@.Charges
Iterate @.Self{TaxAndGovernmentDetailCharge}.Fees From 1 To #@.Self{TaxAndGovernmentDetailCharge}.Fees
If ( @.FeeScheduleType = "Recording" and Not IsEmpty(@.Amount) ) Then
Value = Value + 4
EndIf
Loop
Loop
Loop
Loop

// CSS - Count each Document in with Fee Schedule type Recording with an Amount filled in
ElseIf ({{Order.SettlementType}} = "CSS") Then
Iterate {{Order.CSSs}} From 1 To #{{Order.CSSs}}
Iterate @.Sections From 1 To #@.Sections
Iterate @.Lines From 1 To #@.Lines
Iterate @.Charges From 1 To #@.Charges
If ( @.Type = "RecordingTransferTax" ) Then
If ( @.Calculation{CSSTaxAndGovernmentChargeCalculation}.FeeScheduleType = "Recording" and Not IsEmpty(@.Amount) ) Then
Value = Value + 4
EndIf
EndIf
Loop
Loop
Loop
Loop
EndIf

This works perfectly, thank you!